#// preview.awk
#// Preview a post in the post edit interface
#// 25.04.2015
#// 
#// Copyright (C) 2015  Balthasar Szczepański
#// 
#// This program is free software: you can redistribute it and/or modify
#// it under the terms of the GNU Affero General Public License as
#// published by the Free Software Foundation, either version 3 of the
#// License, or (at your option) any later version.
#// 
#// This program is distributed in the hope that it will be useful,
#// but WITHOUT ANY WARRANTY; without even the implied warranty of
#// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#// GNU Affero General Public License for more details.
#// 
#// You should have received a copy of the GNU Affero General Public License
#// along with this program.  If not, see <http://www.gnu.org/licenses/>.

BEGIN{
	sentpath="/eizm/mem/t1i/mpost/sent/"
	waitpath="/eizm/mem/t1i/mpost/"
	
	HTML="<div class=\"pl\"><div class=\"pls\">Preview: %s</div><div class=\"plw\">%s</div></div><br>"
	wrong="<div class=\"plt\"><b>%s</b></div>\n"
	subject="<input type=\"text\" name=\"subject\" id=\"subject\" size=\"40\" maxlength=\"60\" tabindex=\"1\" value=\"%s\" class=\"pt\">\n"
	username="<input tabindex=\"2\" name=\"username\" id=\"username\" size=\"40\" value=\"%s\" class=\"pt\" type=\"text\">\n"
	time="<b>Y: </b><input tabindex=\"4\" name=\"y\" id=\"year\" size=\"4\" value=\"%s\" class=\"pt\" type=\"text\"><b> M: </b><input tabindex=\"5\" name=\"m\" id=\"month\" size=\"2\" value=\"%s\" class=\"pt\" type=\"text\"><b> D: </b><input tabindex=\"6\" name=\"d\" id=\"day\" size=\"2\" value=\"%s\" class=\"pt\" type=\"text\"><b> H: </b><input tabindex=\"7\" name=\"h\" id=\"hour\" size=\"2\" value=\"%s\" class=\"pt\" type=\"text\">\n"
	message="<textarea name=\"message\" id=\"message\" rows=\"17\" tabindex=\"8\" class=\"pt\" >%s%s</textarea>\n"
	# forcetime1="<input type=\"text\" name=\"forcetime\" id=\"forcetime\" size=\"16\" maxlength=\"32\" value=\"%s\" class=\"pt\">\n"
	# forcetime2="<tr><td><b>fTime: </b></td><td><b>day: </b><input name=\"dd\" id=\"fday\" size=\"2\" value=\"%s\" class=\"pt\" type=\"text\"><b> month: </b><input name=\"mm\" id=\"fmonth\" size=\"2\" value=\"%s\" class=\"pt\" type=\"text\"><b> year: </b><input name=\"yy\" id=\"fyear\" size=\"4\" value=\"%s\" class=\"pt\" type=\"text\"></tr>\n"
	# img="<input type=\"button\" class=\"pk\" accesskey=\"p\" name=\"addbbcode14\" value=\"Img\" style=\"width: 40px\" onclick=\"bbstyle(14)\" title=\"Insert image: [img]http://image_url[/img]\" >"
	back="<a href=\"/silentbot/list\">back to the Silent Chronotransponder</a>"
	
	disable_bbcode="<input class=\"pt\" type=\"checkbox\" name=\"disable_bbcode\" id=\"disable_bbcode\" %s > <b>Disable BBcode</b><br>\n"
	disable_smilies="<input class=\"pt\" type=\"checkbox\" name=\"disable_smilies\" id=\"disable_smilies\" %s > <b>Disable smilies</b><br>\n"
	disable_magic_url="<input class=\"pt\" type=\"checkbox\" name=\"disable_magic_url\" id=\"disable_magic_url\" %s > <b>Do not automatically parse URLs</b><br>\n"
	attach_sig="<input class=\"pt\" type=\"checkbox\" name=\"attach_sig\" id=\"attach_sig\" %s > <b>Attach a signature</b><br>\n"
	notify="<input class=\"pt\" type=\"checkbox\" name=\"notify\" id=\"notify\" %s > <b>Notify me when a reply is posted</b><br>\n"
	silent="<input class=\"pt\" type=\"checkbox\" name=\"silent\" id=\"silent\" %s > <b>Very silent</b><br>\n"
	
	forceID="<input type=\"hidden\" name=\"forceID\" value=\"%s\">\n"
	forcekey="<input type=\"hidden\" name=\"forcekey\" value=\"%s\">\n"
	
	addquote=""
	
	# print "<!--preview.awk:\nargfile=" argfile
	while((getline argline < argfile)>0)
	{
		gsub(/[\r\n]/,"",argline)
		eq=index(argline,"=")
		argtab[substr(argline,1,eq-1)]=substr(argline,eq+1)
		# print substr(argline,1,eq-1) "=" argtab[substr(argline,1,eq-1)]
	}
	# print "-->"
	close(argfile)
	if(argtab["edit"] ~ /^wt[0-9]+_[0-9a-fA-F]+$/)
	{
		argtab["forceID"]=substr(argtab["edit"],3)
		argfile= waitpath argtab["forceID"]
		
		while((getline argline < argfile)>0)
		{
			gsub(/[\r\n]/,"",argline)
			eq=index(argline,"=")
			if(argline ~ /^key=/)
			{
				if(substr(argline,eq+1)!=key && argtab["addquote"]~/^wt/)
				{
					argtab["wrong"]="Invalid key."
					break;
				}
				argtab["key"]=substr(argline,eq+1)
			}
			else if(argline ~ /^((username)|(subject))_h=/)
				argtab[substr(argline,1,eq-3)]=substr(argline,eq+1)
			else if(argline ~ /^BBHTML=/)
			{
				argtab["message"]=substr(argline,eq+1)
				gsub(/<br>/,"\n",argtab["message"])
			}
			else if(argline ~ /^((BB)|(username)|(subject)|(message)|(HTML)|(debug))=/)
			{}
			else
				argtab[substr(argline,1,eq-1)]=substr(argline,eq+1)
		}
		close(argfile)
	}
	else if(argtab["addquote"] ~ /^[sw]t[0-9]+_[0-9a-fA-F]+$/)
	{
		if(argtab["addquote"] ~ /^st[0-9]+_[0-9a-fA-F]+$/)
			argfile= sentpath substr(argtab["addquote"],3)
		if(argtab["addquote"] ~ /^wt[0-9]+_[0-9a-fA-F]+$/)
			argfile= waitpath substr(argtab["addquote"],3)
		#else
			#argfile is not changed = quote self?
		while((getline argline < argfile)>0)
		{
			gsub(/[\r\n]/,"",argline)
			eq=index(argline,"=")
			if(argline ~ /^key=/)
			{
				if(substr(argline,eq+1)!=key && argtab["addquote"]~/^wt/)
				{
					argtab["wrong"]="Invalid key."
					break;
				}
			}
			if(argline ~ /^BBHTML=/)
			{
				addquotehtml=substr(argline,eq+1)
				gsub(/<br>/,"\n",addquotehtml)
			}
			if(argline ~ /^username_h=/)
				addquotename=substr(argline,eq+1)
			if(argline ~ /^subject_h/)
			{
				addquotesub=substr(argline,eq+1)
				if(addquotesub ~ /^Re:/)
					argtab["subject"]=addquotesub
				else
					argtab["subject"]="Re: "addquotesub
			}
			if(argline ~ /^y=/)
			{
				argtab["y"]=substr(argline,eq+1)
			}
			if(argline ~ /^d=/)
			{
				argtab["d"]=substr(argline,eq+1)
			}
			if(argline ~ /^m=/)
			{
				argtab["m"]=substr(argline,eq+1)
			}
			if(argline ~ /^h=/)
			{
				argtab["h"]=substr(argline,eq+1)
			}
		}
		close(argfile)
		if(addquotehtml!="")
			addquote="[quote=&quot;"addquotename"&quot;]"addquotehtml"[/quote]"
	}
};
{
	if ($0 ~ /^###HTML/)
	{
		if((argtab["HTML"]!="")&&(argtab["wrong"]==""))
			printf(HTML,argtab["subject"],argtab["HTML"])
	}
	else if ($0 ~ /^###wrong/)
	{
		if(argtab["wrong"]!="")
			printf(wrong,argtab["wrong"])
	}
	else if ($0 ~ /^###subject/)
			printf(subject,((argtab["subject"]=="")?"Wait for it.":argtab["subject"]))
	else if ($0 ~ /^###username/)
		printf(username,argtab["username"])
	else if ($0 ~ /^###message/)
		printf(message,argtab["message"],addquote)
	else if ($0 ~ /^###time/)
		printf(time,argtab["y"],argtab["m"],argtab["d"],argtab["h"])
	
	else if ($0 ~ /^###future/)
	{
		###no longer supported
	}
	else if ($0 ~ /^###forceID/)
	{
		if(argtab["forceID"]!="")
			printf(forceID,argtab["forceID"])
	}
	else if ($0 ~ /^###forcekey/)
	{
		if(argtab["key"]!="")
			printf(forcekey,argtab["key"])
	}
	else if ($0 ~ /^###back/)
	{
		print back
	}
	else if ($0 ~ /^###debug/)
	{
		gsub(/###nl;/,"\n",argtab["debug"])
		gsub(/-/," - ",argtab["debug"])
		print "<!-- "argtab["debug"]" -->"
	}
	else if ($0 ~ /^###disable_bbcode/)
		printf(disable_bbcode,(argtab["disable_bbcode"]=="on")?"checked=\"checked\"":"")
	else if ($0 ~ /^###disable_smilies/)
		printf(disable_smilies,(argtab["disable_smilies"]=="on")?"checked=\"checked\"":"")
	else if ($0 ~ /^###disable_magic_url/)
		printf(disable_magic_url,(argtab["disable_magic_url"]=="on")?"checked=\"checked\"":"")
	else if ($0 ~ /^###attach_sig/)
		printf(attach_sig,(argtab["attach_sig"]=="on")?"checked=\"checked\"":"")
	else if ($0 ~ /^###notify/)
		printf(notify,(argtab["notify"]=="on")?"checked=\"checked\"":"")
	else if ($0 ~ /^###silent/)
		printf(silent,(argtab["silent"]=="on")?"checked=\"checked\"":"")
	else
		print $0
};